eCircuit  Center

 


About SPICE | SPICE Basics | Running SPICE | CIRCUIT COLLECTION | SPICE Commands | SPICE Demos and Downloads
About Us | Contact Us | Home

 

 

3 Op Amp Instrumentation Amplifier

CIRCUIT

                             INSTAMP1.CIR                Download the SPICE file

Instrumentation amplifiers are actually made up of 2 parts: a buffered amplifier XOP1, XOP2 and a basic differential amplifier XOP3. The differential amplifier part is often essential when measuring sensors. Why? A sensor produces a signal between its terminals. However, for some applications, neither terminal may be connected to the same ground potential as your measuring circuit. The terminals may be biased at a high potential or riding on a noise voltage. The differential amplifier rescues the signal by directly measuring the difference between the sensor’s terminals.

The buffered amplifier XOP1 and XOP2 not only provides gain, but prevents the sensor resistance from affecting the resistors in the op amp circuit, and vice-versa!

  

SIGNAL GAIN

The instrumentation amp offers two useful functions: amplify the difference between inputs and reject the signal that’s common to the inputs. The latter is called Common Mode Rejection (CMR). The signal gain is accomplished by XOP1 and XOP2 while XOP3 typically forms a differential gain of 1. You can calculate the overall gain by

 

where R1=R3 and R5/R4 = R7/R6.

 The SPICE circuit applies a differential signal VS (1V @ 10kHz) and a common mode signal VCM (5V @ 1kHz) to the amplifier’s inputs. With R1 = 10k, R2 = 2k and R4,5,6,7 = 10k, the circuit delivers a differential gain of Vo/Vs = (1+ 2 x 10/2) = 11. Run a simulation and check out the input V(2) and output V(10) voltages. Did the circuit amplify the 10 kHz input and reject the 1 kHz common mode signal?

 HANDS-ON DESIGN  Suppose you need more gain to amplify a small signal (10 mV) from a pressure or temperature sensor. Design a circuit to punch up the level to the 1 to 10V range that’s practical for an ADC input. ( For example, R1=10k and R2 = 200 makes a gain of (1 + 2 x 10000/200) = 101 increasing the 10 mV signal to 1.01 V) You can change the input signal value to 10 mV in the VS statement

      VS    2     1      SIN(0  0.010  10KHZ)

Test drive your new circuit. Remember the 10mV signal is still riding on the whopping 5V common-mode signal.

  

COMMON MODE REJECTION

 CIRCUIT ANALYSIS   One way to test CMR is to kill voltage source VS and see how much of VCM gets through to the output. Set VS to 0V by the statement

           VS    2     1      SIN(0  0  10KHZ)

To get a closer view of the output, plot V(10) only. Try the circuit and see how much VCM squeaks through.

 

RESISTOR MATCHING

One factor that determines the health of CMR is the matching of resistor values. (The other is the CMR of the op amp device itself which is ideal for this op amp model. We’ll look at modeling op amp CMR in the future.)

 CIRCUIT ANALYSIS  Suppose just one of the resistors is off by only 0.1%.  Change any one of resistors R4,5,6 or 7 to 10.1 k or 9.99 k. Set VS to 0V as described in the section above. Can you see an increase in the output from VCM? For precise measurements, an error of only a few milli-volts can wreck the required performance of your measuring system.

 

SIMULATION NOTE

The op amp is modeled using a subcircuit named OPAMP1. Although the guts of an op amp can contain 20 transistors or more, this model mimics only the higher level (or macro) functions of the device. The result is a simple model requiring only a handful of components. For a more detailed look inside, see the Basic Op Amp Model.

Subcircuits are handy ways of inserting a particular circuit into one or more places of the main circuit. They're easy to define and use. Check them out in Why Use Subcircuits?

 

SPICE FILE

Download the file or copy this netlist into a text file with the *.cir extention.

INSTAMP1.CIR - 3 OPAMP INSTRUMENTATION AMPLIFIER
*
VS		2	1	SIN(0	1	10KHZ)
VCM	1	0	SIN(0	5	1KHZ)
*
* BUFFERED AMPLIFIER
XOP1	2 4	6	OPAMP1
R1	4	6	10K
R2	4	5	200
R3	5	7	10K
XOP2	1 5	7	OPAMP1
* DIFFRENTIAL AMPLIFIER
R4	6	8	10K
R5	8	10	10K
R6	7	9	10K
R7	9	0	10K
XOP3	9 8	10	OPAMP1
*
* OPAMP MACRO MODEL, SINGLE-POLE 
* connections:      non-inverting input
*                   |   inverting input
*                   |   |   output
*                   |   |   |
.SUBCKT OPAMP1      1   2   6
* INPUT IMPEDANCE
RIN	1	2	10MEG
* GAIN BANDWIDTH PRODUCT = 10MHZ
* DC GAIN (100K) AND POLE 1 (100HZ)
EGAIN	3 0	1 2	100K
RP1	3	4	1K
CP1	4	0	1.5915UF
* OUTPUT BUFFER AND RESISTANCE
EBUFFER	5 0	4 0	1
ROUT	5	6	10
.ENDS
* 
* ANALYSIS
.TRAN 	0.01MS  1.0MS
* VIEW RESULTS
.PLOT	TRAN 	V(2) V(10)
.PRINT TRAN V(2) V(10)
.PROBE
.END

 

top

© 2002 eCircuit Center